/* Lesson 12-01 */
 /*    File Name = les1201.sas  01/11/22   */

options nocenter linesize=78 pagesize=30;
options locale='en_US';
/* options locale='ja_JP'; */
proc printto print = 'StatM21/les1201-Results.txt' new;

data gakusei;
  infile 'StatM21/StudAll21d.csv'
    firstobs=9 dlm=',' dsd missover 
    encoding=sjis termstr=crlf;
  input sex $ shintyou taijyuu kyoui 
        jitaku : $10. kodukai carryer $ tsuuwa;

proc print data=gakusei(obs=5);
run;

title '*** データ全体を対象に ***';
proc freq data=gakusei;
  table sex;
run;

proc means data=gakusei;
  var shintyou taijyuu; 
run;

ods listing;
ods graphics off;
proc univariate data=gakusei plot;
  var shintyou taijyuu; 
run;
ods graphics on;
ods listing close;

/* 性別ごとに(方法1) */
title '*** 性別ごとに平均値(方法1) ***';
proc means data=gakusei;
  where sex="M";
  var shintyou taijyuu; 
run;

proc means data=gakusei;
  where sex="F";
  var shintyou taijyuu; 
run;

/* 性別ごとに(方法2) */
title '*** 性別ごとに平均値(方法2) ***';
proc sort data=gakusei;
  by sex;
run;

proc means data=gakusei;
  var shintyou taijyuu; 
  by sex;
run;

ods listing;
ods graphics off;
proc univariate data=gakusei plot;
  var shintyou taijyuu kyoui kodukai; 
  by sex;
run;
ods graphics on;
ods listing close;

/* グラフィック出力(キャラクタグラフではない) */
proc univariate data=gakusei plot;
  var shintyou taijyuu kyoui kodukai; 
  by sex;
run;

/* 性別ごとにヒストグラム(方法1) */
title ' *** 性別ごとにヒストグラム(方法1) ***';
proc chart data=gakusei;
  hbar shintyou taijyuu;
  by sex;
run;

/* 性別ごとにヒストグラム(方法2) */
title '*** 性別ごとにヒストグラム(方法2) ***';
proc chart data=gakusei;
  hbar shintyou taijyuu/group=sex;
run;