Some Tips of SAS : SAS を使う上でのちょっとしたヒント

SAS を活用する時に知っていると重宝するテクニックをまとめておきます。

データの生成 : 乱数で(正規乱数)

data test;
 do i=1 to 10;
   x=rannor(20394);
   output;
 end;
run;

2番から5番の表示

proc print data=test(firstobs=2 obs=5);
run;

これは文法間違い

proc print data=test;
 where( 2 <= _n_ <= 5);
run;

データのアスキー保存

data _null_;
 set test;
 file "c:\foo.txt";
 put i 2. x 12.5;
run;

データのバイナリー保存 : まず、ディレクトリ名を指定。その後、保存。
```
libname perm "e:\sasdata";

data perm.foobar;
 set test;
run;
```
バイナリーデータの使用(呼び出し)
```
data test1;
 set perm.foobar;
run;
```
3番目から4番目のデータについて平均を取る
```
proc means data=test(firstobs=3 obs=4);
run;
```
行末がそろってないデータの読み込み : missover ってのもあるにはある
```
data math;
  infile 'R:\foo.dat'
     obs=10000
     truncover 
     lrecl=530;
```

降順と昇順のヒストグラム

data test;
 do i=1 to 100;
  x=rannor(20394);
  output;
 end;
run;

title "Default";
proc chart data=test;
 hbar x;
run;

title "Ascending";
proc chart data=test;
 hbar x / midpoints=-3 to 3 by .5;
run;

title "Descending";
proc chart data=test;
 hbar x / midpoints=3 to -3 by -.5;
run;

title;

データファイルの先頭 3行を読み飛ばす(コメント等が挿入されている場合)
```
data math;
  infile 'R:\foo.dat' firstobs=4;
```
1レコードのレコード長が長い場合
```
data math;
  infile 'R:\foo.dat' lrecl=200;
```
CSV 形式のファイルを読む場合 : デリミタの指定
[コメント] 以下の指定を行っても「,,」と言うようにコンマが続いている(欠損値) CSV 形式のファイルはうまく読めないようである。エディタ等で事前に「, ,」や「,0,」と置換しておく必要がある。
data mon2002; infile 'd:\home\monitor\assign2002\ver2\mon_all8d.csv' dlm=',' firstobs=2 truncover;
CSV 形式のファイルを読み込む場合、文字列の長さを指定しないと、 8文字(8バイト)しか読み込んでくれない。しかし、かと言って、input 文に文字数を指定すると、カンマを超えて読み込もうとする。そのような場合は、 data 文の中で、文字数を事前に指定してやれば対処できる。具体的には
data daigaku05; length unin $ 20.; infile 'd:\home\monitor\assign2002\ver2\mon_all8d.csv' dlm=',' firstobs=2 truncover; input id $ unin $ depn $ ;
とすれば良い。これを以下のように指定すると、カンマを超えて読み込んでしまう(悪い例)。
data daigaku05; infile 'd:\home\monitor\assign2002\ver2\mon_all8d.csv' dlm=',' firstobs=2 truncover; input id $ unin $ 20. depn $ ;
文字データの読み込み時に便利なコマンド
　inputコマンドにおいて、文字データ($ マークで指定)は何も指定しない(デフォルト)と8文字しか読み込まないので、長いデータ(以下の例の氏名等)はそのままでは後ろ側が切れてしまう。
　これに対処するために、文字列の長さを「 Univ $24. 」と指定することができる(データ中最大の長さを指定する。最後のピリオドを忘れないように)。が、今度はデータ中の短い文字列を読んだ際に、カンマを超えてその後ろまでもが一つのデータであると誤認してしまい、うまく読み込めない。それらの欠点を一挙に解決するには以下の様式のプログラムを用いる。続く欠損値を個々にバラして読ませ(infile 中の dsd)、デリミタが出現するところまでの任意の長さの文字列を読み込む(input 中の : )ように指定し、「 Univ : $24. 」と指定する。
　csv ファイルを読み込む場合には頻繁に利用されるので、覚えておくと重宝する。
```
data Sogo;
  infile 'C:\foo\総合試験実施大学一覧l.csv' 
         firstobs=6 
         truncover lrecl=240
         dlm=','  dsd missover
;
  input No $ Univ : $30. SName : $40. Faculty : $50. Dept : $50. 
        Center1 : $8. Center2 : $8. Sel1 : $8. Sel2 : $8. 
        Book1 : $10. Book2 : $10. 
        Vol0  VolS  VolT  
        ZenKou $ ScoreS  ScoreT  KoKouSi  
;
```

タブ区切り形式のファイルを読む場合 : デリミタの指定

data mon2002;
  infile 'd:\home\monitor\assign2002\ver2\mon_all8d.txt' dlm='09'x 
         firstobs=2
         truncover;

固定長データの場合 : カラム指定

input
      id       $  7-11
      Cage     $ 14-15
      Csex     $ 22
      Sgr1       33-35
      Sgr2       41-43
      Sgr3       47-49
      Stotal     53-55
;

文字コードと行末コードの指定(必要に応じて)
　Windows で作成したファイルは、文字コードがShift-JISで、行末コードが「キャリッジリターン(CR)＋改行(LF)」となっている。しかし、SASでは文字コードのデフォルトが UTF-8、行末コードが「キャリッジリターン(CR)」となっているので、 Windowsから転送したファイルを読み込む際にはこれらを指定する必要がある。
[コマンド] : encoding=sjis　termstr=crlf
[参考] : テキスト・ファイルの行末コードを変更する
- Windows: Shift-JIS [sjis], CR+LF [crlf]
- UNIX: EUC [jeuc] or UTF-8 [utf8], LF [lf]
- Mac: UTF-8 [utf8], CR [cr]
- CR=Carriage Return, 本来の意味は「カーソルを左端に戻す」
- LF=Line Feed, 本来の意味は「改行」
- [補足1] 漢字コードがUTF-8の場合、「utf8」とするか「'utf-8'」(クォーテーションで囲む)と指定すべきであることが判明しました。
  - 参考ページ: データのトランスコーディングに使用するSBCS、DBCSおよびUnicodeエンコーディング値
- [補足2] Mac のExcel で csvファイルを作成した場合の漢字コードは UTF-8 のようですが、行末コードが何になるかが調べても正確には判りませんでした。ただ、1例だけを挙げると「CR+LF」になっていましたので、常時「CR」ではない可能性があります。今後も調べてみますが、現状で判っていることをお知らせしておきます。

ケースをわたって値を保持する変数 : retain ステートメント [ 実行結果 ]
[参考にしたページ] 任意変数が欠損値のとき、前のオブザベーションの欠損値ではない値のセット方法

/* global01.sas */
/*    File Name = global01.sas   10/21/04   */
/*                                          */
/*  ケースをわたって値を保持する変数        */
/*   [例] ある変量の総和を求めたい          */

options nocenter linesize=78 pagesize=9999;

DATA sample;
   INPUT Sgr1 Sgr2 Sgr3;
CARDS;
30   17   24
34   17   33
53   35   56
61   30   50
57   21   55
62   34   55
56   23   49
57   23   55
57   21   42
56   26   49
;
run;

proc print data=sample;
run;

proc means data=sample  maxdec=2  n mean sum;
  var Sgr1 Sgr2 Sgr3;
run;

title "*** global variable ***";
data tmp1;
  RETAIN sum1-sum3 0.0;
  set sample;
  sum1=sum1+Sgr1;
  sum2=sum2+Sgr2;
  sum3=sum3+Sgr3;
run;

proc print data=tmp1;
  var sum1-sum3;
run;

変数名は~~8文字以内 : これはすごく厳しい制限だと思う。~~ 現在は32文字だったかなぁ
文字型変数の保持できる文字列長も 8文字か?
Win 版 SAS でバッチ的に実行する方法 (現在未確認。一部想像モード)
```
sas.exe source.sas -print listfile.lst -log logfile.log
```

freq において、全体パーセントや行パーセント、列パーセントを表示させない

proc freq data=gakusei;
  tables OYear*OTerm;
  tables ID*SCatG / nopercent norow nocol;
  tables ID*Bunri / nopercent norow nocol;
run;

means において、表示させる変量を指定する

proc means data=gakusei SUM MEAN MIN MAX;
  var Unit;
  by SCatS;
  class ID;
  output out=omean1 N=n1 SUM=su1 MEAN=me1 MIN=mi1 MAX=ma1;
run;

boxplot (最小値・最大値までひげを伸ばさないようにするオプション)と scatterplot matrix

ods listing gpath='/folders/myfolders/foo/SAS_ODS01';

proc boxplot data=TK2;
  plot ScoreA*SubA / BOXSTYLE=SCHEMATIC;
run;

proc sgscatter data=TK2;
  title "Scatterplot Matrix for TK2";
  matrix ScoreA ScoreB ScoreC ScoreT;
run;
  title "";

SAS に関するページ

私の非常勤講義のページ
お役立ちサイト
- Base SAS 9.2 Procedures Guide
  - 左側のProcedures: 各種手法(主に基礎的手法)の使い方やExampleが掲載されている。
    - [例] means, univariate, freq, plot, sort
- SAS/STAT 9.2 User's Guide, Second Edition
  - 左側のProcedures: 各種手法(上記以外)の使い方やExampleが掲載されている。
    - [例] reg, princomp, factor, fastclus
- サンプルデータ: データの説明とその使い方が掲載されている。
  - Sashelp Data Sets - SAS Support (PDF ファイル)
  - SAS/STAT 9.3 User's Guide
    - 左側の項目: Sashelp Data Sets

初回登録日 : 2000年11月最終修正日 : 2018年12月

Atsuhiro Hayashi (hayashi.atsuhiro_at_nitech.ac.jp)

Computer Tips ページへ戻ります